home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Apple II Magazines (DO)
/
Softdisk Magazette Volume 1, No. 11 (1982-07)(Softdisk)(Side B).zip
/
Softdisk Magazette Volume 1, No. 11 (1982-07)(Softdisk)(Side B).do
/
RECORD.TIMER.bas
< prev
Wrap
BASIC Source File
|
1996-12-24
|
2KB
|
53 lines
10 REM * RECORD ==> TAPE TIMING GUIDE
20 REM
30 REM * VERSION OF 30 JANUARY 1982
40 REM
50 REM * PROGRAMMED BY: RALPH W. KIEFER
60 REM
100 REM >>> START-UP STUFF <<<
110 N = 18:A = 10:B = 18:C = 26:D = 5
120 DIM M(N),M$(N),MT(N),S(N),ST(N)
500 REM >>> DISPLAY INSTRUCTIONS AND SELECT TIMING GAP <<<
510 HOME
520 PRINT " RECORD ==> TAPE TIMING GUIDE"
530 PRINT " ----------------------------": PRINT : PRINT
540 PRINT "THIS PROGRAM WILL ADD TOGETHER THE TIME OF UP TO 18 SELECTIONS."
550 PRINT : PRINT
560 PRINT "THE PROGRAM ASSUMES 5 SECONDS BETWEEN SELECTIONS.": PRINT : PRINT
565 PRINT "WHEN YOU WISH TO CLEAR THE SCREEN AND BEGIN AGAIN, TYPE IN 'END' WHEN ASKED FOR THE NUMBER OF MINUTES.": PRINT : PRINT : PRINT
570 INPUT " DO YOU WISH TO CHANGE THE 5 SECOND VALUE? (DEFAULT = NO) ";ANS$
580 IF LEFT$(ANS$,1) = "Y" THEN GOSUB 3000
1000 REM >>> CALCULATE/PRINT VALUES <<<
1010 HOME
1020 HTAB A: PRINT "NO";
1030 HTAB B: PRINT "MIN";
1040 HTAB C: PRINT "SEC"
1100 HTAB A: PRINT "--";
1110 HTAB B: PRINT "---";
1120 HTAB C: PRINT "---"
1130 PRINT
2000 FOR I = 1 TO N
2010 VTAB 3 +I: HTAB A: PRINT I;
2020 HTAB B: INPUT " ";M$(I)
2021 IF M$(I) = "END" THEN RUN 100
2022 M(I) = VAL(M$(I))
2025 VTAB 5 +I: HTAB 1: CALL -868: VTAB 3 +I
2030 VTAB 3 +I: HTAB C: INPUT " ";S(I)
2040 IF S(I) >59 THEN 2030
2100 MT(I) = MT(I -1) +M(I)
2110 ST(I) = ST(I -1) +S(I)
2120 FOR J = 1 TO 2
2130 IF ST(I) >59 THEN ST(I) = ST(I) -60:MT(I) = MT(I) +1
2140 NEXT J
2210 VTAB 6 +I: HTAB A: INVERSE : PRINT "TOTAL";: NORMAL : HTAB B +1: INVERSE : PRINT MT(I);: NORMAL : HTAB C +1: INVERSE
2215 IF ST(I) <10 THEN PRINT " ";
2220 PRINT ST(I): NORMAL
2900 ST(I) = ST(I) +D
2950 NEXT I
2980 PRINT
2990 INPUT "HIT RETURN TO RE-RUN PROGRAM";F$
2995 RUN 100
3000 REM >>> SELECT NEW TIME BETWEEN SELECTIONS <<<
3010 PRINT : PRINT
3020 INPUT "TIME BETWEEN SELECTIONS = ";D
3030 RETURN